The monetization engine for indie Godot games.

# shop.gd: talking to PowerUp from your game
func _ready() -> void:
    PowerUp.initialize("YOUR_PUBLISHABLE_KEY", save.client_id, {
        "baseUrl": API_URL, "client": "mygame/1.0.0",
    })
    PowerUp.player_token_issued.connect(func(token: String) -> void: save.token = token)
    if save.token != "":
        PowerUp.set_player_token(save.token)
    else:
        await PowerUp.register_player(save.client_id, save.display_name)

    var store: Dictionary = await PowerUp.fetch_storefront()
    if store.ok:
        %Shop.show(store.storefront.offers)   # your UI, or the bundled storefront node

# Web and desktop use Stripe Checkout. Phones: create_purchase_intent(),
# the store sheet, then submit_receipt().
var _checkout: Dictionary = {}

func _on_product_sheet_opened(sku_key: String) -> void:
    _checkout = await PowerUp.start_checkout(sku_key)   # create it while the sheet opens

func _on_pay_pressed() -> void:
    # Open it right away. After an await, the browser would block the popup.
    if _checkout.get("ok", false) and not PowerUp.open_checkout(_checkout.checkout):
        %ContinueInThisTab.show()   # its button: start a "redirect" checkout (see the Stripe guide)

func _on_watch_for_coins() -> void:
    var ad: Dictionary = await PowerUp.create_ad_session("free_coins")
    if not ad.ok:
        return   # cooldown, daily cap or age gate; ad.code says which
    # ...show the rewarded ad with your ad plugin, then:
    await PowerUp.complete_ad_session(ad.session.sessionId, "admob", true)